News:这是一个新的Typecho主题,如果使用问题请反馈给我QQ1989473781

易语言实现读取任意ACCESS到高级表格

忧郁之子 186 0 条

这篇文章主要介绍了易语言实现读取任意ACCESS到高级表格功能,结合数据库、记录集、高级表格相关操作技巧,实现快速读取access到高级表格,需要的朋友可以参考下

.版本 2
.支持库 eDB
.支持库 eGrid

.子程序 ACCESS到高级表格, 逻辑型, 公开, 将已知ACCESS数据库内容导入到指定窗口的高级表格组件上,注意,指定窗口必须同时具有数据库连接,记录集和高级表格组件。
.参数 数据库连接, 数据库连接
.参数 记录集, 记录集
.参数 ACCESS数据库, 文本型, , 全路径ACCESS数据库名
.参数 数据库表名称, 文本型
.参数 密码, 文本型, 可空
.参数 高级表格, 高级表格
.局部变量 字段数, 整数型
.局部变量 记录数, 整数型
.局部变量 文本, 文本型
.局部变量 i
.局部变量 k

.如果 (数据库连接.连接Access (ACCESS数据库, 密码))
    记录集.置连接 (数据库连接)
    记录集.打开 (数据库表名称, #数据表名)

    字段数 = 记录集.字段数量 + 1
    记录数 = 记录集.记录数量 + 1
    高级表格.行数 = 记录数
    高级表格.列数 = 字段数

    .变量循环首 (1, 字段数, 1, i)
        高级表格.置数据 (0, i, #表格常量.文本型, 记录集.取字段名 (i - 1))
    .变量循环尾 ()

    .变量循环首 (1, 记录数, 1, i)
        高级表格.置数据 (i, 0, #表格常量.文本型, 到文本 (i))
    .变量循环尾 ()

    .变量循环首 (1, 记录数, 1, k)
        .变量循环首 (1, 字段数, 1, i)
            记录集.读文本 (i - 1, 文本)
            高级表格.置数据 (k, i, #表格常量.文本型, 文本)
        .变量循环尾 ()
        记录集.到下一条 ()
    .变量循环尾 ()

    数据库连接.关闭 ()
    返回 (真)

.否则
    信息框 (数据库连接.最后错误, 0, )
    返回 (假)
.如果结束

运行结果图:
accesstogrid.png

发表我的评论

Hi,您需要填写昵称和邮箱!

  • 昵称 (必填)
  • 邮箱 (必填)
  • 网址
欢迎光临轩宇网工作室